热键多击判断库

多击检测1号 := new 多击检测("a", "a_callBack")  ; 拦截并检测a键的多击情况，结果返回到函数 a_callBack()
多击检测2号 := new 多击检测("~b", "b_callBack") ; 检测b键的多击情况，结果返回到函数 b_callBack()

Sleep 5000

多击检测2号.Close() ; 必须手动调用 .Close() 方法关闭
多击检测2号 := ""
MsgBox 0x42030, 关闭热键演示, 多击检测2号已关闭
return

a_callBack(i) {
  ToolTip %i%击了a
}

b_callBack(i) {
  ToolTip %i%击了b
}

class 多击检测 {  ; By 空
  __New(key, fnCallback) {
    this.key        := key
    this.keystrokes := 0
    this.fnCallback := fnCallback
    boundFunc       := ObjBindMethod(this, "_Press")
    this.boundFunc  := &boundFunc
    Hotkey % this.key, % boundFunc
  }

  _Press() {
    if (this.keystrokes = 0) {
      boundFunc := ObjBindMethod(this, "_Checker")
      SetTimer % boundFunc, -400
    }
    this.keystrokes += 1
  }

  _Checker() {
    fnName := this.fnCallback
    %fnName%(this.keystrokes)
    this.keystrokes := 0
  }

  ; Hotkey 会保留 boundFunc 的引用，所以在 ObjRelease 前无法触发 __Delete()，所以只能手动释放
  Close() {
    Hotkey % this.key, Off
    ObjRelease(this.boundFunc)
  }
}